what is drive_channel in ATPase Ca-pump

[emu]

Hi all,

I am trying to include a calcium pump to my model whose Ca2+ pump was described in the original paper as:

fluxpump= Apump [Ca]i / (Kpump + [Ca]i)

where Apump is the max. pumping rate and Kpump is the dissociation constant.

In the modelDB, I found the following mod file which I suppose the right thing I am looking for.

Code: Select all

: $Id: calciumpump_destexhe.mod,v 1.4 1994/04/14 02:47:41 billl Exp $
TITLE decay of internal calcium concentration
:
: Internal calcium concentration due to calcium currents and pump.
: Differential equations.
:
: Simple model of ATPase pump with 3 kinetic constants (Destexhe 92)
:     Cai + P <CaP> Cao + P  (k1,k2,k3)
: A Michaelis-Menten approximation is assumed, which reduces the complexity
: of the system to 2 parameters: 
:       kt = <tot> * k3  -> TIME CONSTANT OF THE PUMP
:	kd = k2/k1 (dissociation constant)    -> EQUILIBRIUM CALCIUM VALUE
: The values of these parameters are chosen assuming a high affinity of 
: the pump to calcium and a low transport capacity (cfr. Blaustein, 
: TINS, 11: 438, 1988, and references therein).  
:
: Units checked using "modlunit" -> factor 10000 needed in ca entry
:
: VERSION OF PUMP + DECAY (decay can be viewed as simplified buffering)
:
: All variables are range variables
:
:
: This mechanism was published in:  Destexhe, A. Babloyantz, A. and 
: Sejnowski, TJ.  Ionic mechanisms for intrinsic slow oscillations in
: thalamic relay neurons. Biophys. J. 65: 1538-1552, 1993)
:
: Written by Alain Destexhe, Salk Institute, Nov 12, 1992
:

INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

NEURON {
	SUFFIX cad
	USEION ca READ ica, cai WRITE cai
	RANGE depth,kt,kd,cainf,taur
}

UNITS {
	(molar) = (1/liter)			: moles do not appear in units
	(mM)	= (millimolar)
	(um)	= (micron)
	(mA)	= (milliamp)
	(msM)	= (ms mM)
}

CONSTANT {
	FARADAY = 96489		(coul)		: moles do not appear in units
:	FARADAY = 96.489	(k-coul)	: moles do not appear in units
}

PARAMETER {
	depth	= .1	(um)		: depth of shell
	taur	= 700	(ms)		: rate of calcium removal
	cainf	= 1e-8	(mM)
	cainit  = 5e-5
	kt	= 1	(mM/ms)		: estimated from k3=.5, tot=.001
	kd	= 5e-4	(mM)		: estimated from k2=250, k1=5e5
}

STATE {
	cai		(mM) 
}

INITIAL {
	cai = cainit
}

ASSIGNED {
	ica		(mA/cm2)
	drive_channel	(mM/ms)
	drive_pump	(mM/ms)
}
	
BREAKPOINT {
	SOLVE state METHOD derivimplicit
}

DERIVATIVE state { 

	drive_channel =  - (10000) * ica / (2 * FARADAY * depth)

	if (drive_channel <= 0.) { drive_channel = 0. }	: cannot pump inward

:	drive_pump = -tot * k3 * cai / (cai + ((k2+k3)/k1) )	: quasistat
	drive_pump = -kt * cai / (cai + kd )		: Michaelis-Menten

	cai' = drive_channel + drive_pump + (cainf-cai)/taur
}

My question is what is the meaning of drive_channel in the DERVATIVE block? As I follow from some papers that the pump description is just the drive_pump. what is the role of drive_channel?

thanks

[Raj]

As far as I can see the drive_channel is part o fthe description of a calcium channel. This mechanism includes both a channnel and a pump.

[ted]

The mechanism is actually a calcium accumulation mechanism. In other
words, it embodies the law of conservation of mass, expressed in the form
cai' = influx_of_ca - efflux_of_ca
You really should read the original paper to understand the authors' intent,
i.e. what they had in mind when they created this model of calcium
accumulation. However, it seems clear that:

• 1. The pump is not allowed to "run backwards."
  2. This accumulation mechanism has a very specific geometry: a thin shell just inside the cell membrane, and a large central core. "cai" is actually calcium concentration in the shell. The concentration in the core is assumed to be constant, with a value of cainf. There is diffusional exchange between the shell and the core, so that if the pump were blocked and there were no calcium flux through ion channels, cai would approach cainf with a monoexponential time course described by time constant taur.

So it's not just a calcium pump. You need to ask yourself whether you want to make the extra assumptions (accumulation in a thin shell, equilibration with a large core). If the answer is no, you'll need to use a different mechanism or modify this one.