No action potentials when antinode>node diameter

[hammond2]

Hi,

I am trying to get action potentials to be generated in the node of Ranvier but can only do so when its diameter is much bigger than the antinode diameter. Does anyone have any suggestions? Thanks for the help!

My code is below:

//Load the standard function library

load_file("nrngui.hoc")

//Create sections

create nodea, nodeb, antinode, transa, transb
access nodea

//Define section properties

nodea {
nseg = 1
diam = 5
L = .35
Ra = 35
insert hh
gnabar_hh=.5
gl_hh = .0001667
el_hh = -60.0
}

transa{
nseg = 1
diam = 5
L = 5
Ra = 123
insert pas
g_pas = .0001667
}

antinode{
nseg = 5
diam = 7.75
L = 1000
Ra = 35
insert pas
g_pas = .0001667
}

transb{
nseg = 1
diam = 7.75
L = 5
Ra = 123
insert pas
g_pas = .0001667
}


nodeb {
nseg = 1
diam = 5
L = .35
Ra = 35
insert hh
gnabar_hh=.5
gl_hh = .0001667
el_hh = -60.0
}



// Connecting sections

connect nodea(1), transa(0)
connect transa(1), antinode(0)
connect antinode(1), transb(0)
connect transb(1), nodeb(0)

// Create the electrode

objectvar stim
stim = new IClamp(0.5)
stim.del = 100
stim.dur = 5
stim.amp = 0.1
tstop = 300

[ted]

Before we even start, here are some comments and suggestions that will prevent much confusion in the very near future.
1. The root section of a model is the section that has no parent.
2. The connect statement
connect a, b
makes b the parent of a.
3. The access statement is generally used to designate which section is conceptually privileged, i.e. "special" in the sense that, if you refer to v without saying which section's v you mean, you are referring to v in the "special" section.
4. In models with simple topology like these, it usually makes sense for the root section and the conceptually privileged section to be the same.

1-4 suggest that it is best to revise your connect statements so that your model's "accessed" section is the same as one of the two root sections in your model.

5. Iterators such as for (x) somestatement (or for (x, 0) somestatement) execute somestatement in the context of the currently accessed section, starting at (or at the internal node nearest to) the 0 end of the section and moving toward its 1 end.
6. It is best if path distance from the root node (the 0 end of the root section) increases as you move from the 0 end of a section toward its 1 end. If this is not the case, space plots (plots of variables such as v vs. distance along a path in a model cell) can look very strange, and algorithmic assignment of parameter values based on path distance from a reference point can result in unexpected distributions of channel densities or other properties in a model cell.

5 and 6 suggest that you revise your connect statements so that they connect the 0 end of each child section to the 1 end of its parent. The sole exception to this would be in the case of a cell model that has one or more neurites attached to each end of the soma, in which case the 0 end of some child section(s) would be connected to the 1 end of the root section, and the 0 end of some child section(s) would be attached to the 0 end of the root section.

I'll leave it up to you to decide exactly what the connect statements should be. After you fix them, we can move on to address the question about excitability.

[hammond2]

I changed my connect statements to

connect transa(0), nodea(1)
connect antinode(0), transa(1)
connect transb(0), antinode(1)
connect nodeb(0), transb(1)

So I made nodea the only root section. Is that correct?

Do you know what the excitability issue is?

[ted]

I changed my connect statements
. . .
So I made nodea the only root section. Is that correct?

Yes, nodea is now the root and the default section, and anatomical distance from the 0 end of nodea increases as one moves from the 0 to the 1 end along each section. Good.

Do you know what the excitability issue is?

Yes. The nodes are too puny to generate enough current for this model to produce a spike. You're going to need gnabar_hh much larger--20 or 25 works, but you'll also have to increase gkbar_hh to pull v back down to rest. And I suspect you'll want to use a much shorter, higher amplitude stimulus current, say 30 nA x 0.1 ms, to get a decent spike initiation (otherwise gna will inactivate and gk will turn on strongly during the stimulus current).