How do I control the rebound current amplitude?

[chalspark]

Hello, Ted

I always thank for your answers.

I've got a some question.

I wonder about "how do i control the rebound current amplitude?"

I used this h-channel model.

Code: Select all

TITLE I-h channel from Magee 1998 for distal dendrites

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)

}

PARAMETER {
	v 		(mV)
        ehd 		(mV)        
	celsius 	(degC)
	ghdbar=.0001 	(mho/cm2)
        vhalfl=-81   	(mV)
	kl=-8
        vhalft=-75   	(mV)
        a0t=0.011      	(/ms)
        zetat=2.2    	(1)
        gmt=.4   	(1)
	q10=4.5
	qtl=1
}


NEURON {
	SUFFIX hd
	NONSPECIFIC_CURRENT i
        RANGE ghdbar, vhalfl
        GLOBAL linf,taul
}

STATE {
        l
}

ASSIGNED {
	i (mA/cm2)
        linf      
        taul
        ghd
}

INITIAL {
	rate(v)
	l=linf
}


BREAKPOINT {
	SOLVE states METHOD cnexp
	ghd = ghdbar*l
	i = ghd*(v-ehd)

}


FUNCTION alpt(v(mV)) {
  alpt = exp(0.0378*zetat*(v-vhalft)) 
}

FUNCTION bett(v(mV)) {
  bett = exp(0.0378*zetat*gmt*(v-vhalft)) 
}

DERIVATIVE states {     : exact when v held constant; integrates over dt step
        rate(v)
        l' =  (linf - l)/taul
}

PROCEDURE rate(v (mV)) { :callable from hoc
        LOCAL a,qt
        qt=q10^((celsius-33)/10)
        a = alpt(v)
        linf = 1/(1 + exp(-(v-vhalfl)/kl))
:       linf = 1/(1+ alpl(v))
        taul = bett(v)/(qtl*qt*a0t*(1+a))
}

I add in myproject IPSP with used conductance.

Code: Select all

NEURON {
	POINT_PROCESS AlphaClamp
	RANGE del, dur, amp, i, alpha, multiple
	ELECTRODE_CURRENT i
}
UNITS {
	(nA) = (nanoamp)
}

PARAMETER {
	v	(mV)
	ehd = -75	(mV)
	del (ms)
	dur (ms)	<0,1e9>
	amp = 0 (nA)
	alpha = 260
	multiple
}
ASSIGNED {
	i (nA)
	galpha
}

INITIAL {
	i = 0
}

BREAKPOINT {
	at_time(del)
	at_time(del+dur)

	if (t <= del+dur && t >= del) {
		galpha = -(((alpha^2*(t-del)*exp(-alpha*(t-del)))*0.0321))*multiple
	}else{
		galpha = 0
	}

	i = galpha*(v-ehd)
}

and then I was simulated my project that just give IPSP at resting situation.

I have got this result.



In this result, rebound current is to much small and I want to increase rebound current.

How do i control(or increase) the rebound current?

Thanks.

[ted]

I wonder about "how do i control the rebound current amplitude?"

But you show membrane potential, so the real question is how to make a larger rebound of membrane potential, right? Possible answers include the following:
1. Increase the conductance density of the h current. The hoc name for this parameter is ghdbar_hd.
2. Decrease the conductance densities of other currents, especially passive or leak currents.
3. Reduce specific membrane capacitance cm.
4. If the model has many sections, and the h current is not present in all sections, increase cytoplasmic resistivity Ra.
5. Change the gating dynamics of the h current so that it turns on faster and turns off slower.
6. Change the voltage dependence of the h current so that it is centered on the range of membrane potentials in which you want to see a big sag or rebound.